윈도우7 uefi 하드 디스크 설치

사용한 노트북 : HP ENVY 15-J022TX
odd 없고 usb3.0으로 4port 구성.

윈도우7 및 uefi를 사용하려는 목적... 속도가 빠르다길래...
bios - 16bit(Interrupt 13 사용. block 단위 전송 - 64Kbyte)
efi - 32bit 또는 64bit(EFI block I/O 프로토콜 사용. 1블럭 전송 - 1Mbyte)

- 바이오스 셋팅에서 Secure boot 메뉴 disable -  출하 시 OS가 윈도우 8이기 때문에 옵션 설정을 하지 않는 경우 윈도우7을 설치할 수 없음
- Legacy Mode - enable - enable로 설정해도 uefi 또는 legacy로 설치 가능(32bit 윈도우 설치 시 사용하지만 노트북 메모리가 8Gbyte라서.....)
- UEFI환경은 64bit 윈도우만 설치 가능. 왜인지는 모르겠지만 XP는 안된다고....

- 실패한 방법
구글링으로 부팅 usb 만들어 적용하였지만 usb메모리가 usb2.0인 관계로 boot.wim을 읽어들인 이후로 install.wim이 없다는 오류 메세지 출력됨.
설연휴라 usb3.0 메모리를 구할 수 없어 포기.

- 성공한 방법
하드디스크를 이용한 방법을 찾던 중 스누피님 블로그(스누피박스)에서 하드디스크로 윈도우7 설치를 참조.
이미 하드 디스크를 초기화한 상태라 윈도우8 수정 ISO 파일을 UltraISO를 이용하여 부팅usb 구성.
(윈도우8의 경우 윈도우7과는 다르게 usb2.0으로 구성해도 윈도우 설치가 가능함)

윈도우8에서 하드 디스크 볼률 조절 후 OS가 설지되지 않은 드라이브에 윈도우7 순정 ISO에서 boot, sources 폴더와 노트북 드라이버 저장.(윈도우7 설치 후 드라이버가 없는 경우 아무 것도 못하는 사태가 발생함)

- 하드디스크에 복사한 Windows7을 BCD에 등록하는 배치 파일
- 스누피님의 설치하기 메뉴.cmd 파일을 efi용으로 수정
- 아래 내용을 복사해서 새로 만들기 > 텍스트 문서에 붙여넣고 파일명의 확장자를 cmd로 저장
==================================================================================================
@echo off
pushd %~dp0
bcdedit > nul
if errorlevel 1 goto _ADMIN

:_SRC
for %%A in (C: D: E: F: G: H: I: J: K: L: M: N: O: P: Q: R: S: T: U: V: W: X: Y: Z:) do (
 if exist %%A\boot\boot.sdi (
  if not exist %%A\setup.exe (
   if exist %%A\sources\boot.wim set SRC=%%A
  )
 )
)

:_RAMDISK
bcdedit /create {ramdiskoptions} /d "Ramdisk 옵션"
bcdedit /deletevalue {ramdiskoptions} description
bcdedit /set {ramdiskoptions} ramdisksdidevice partition=%SRC%
bcdedit /set {ramdiskoptions} ramdisksdipath \boot\boot.sdi
bcdedit /create /d "Windows7 64bit UEFI 설치" /application OSLOADER > GUIDTEMP.TXT

:_KOR
for /F "tokens=1" %%B in (GUIDTEMP.TXT) do (
 bcdedit /set %%B device ramdisk=[%SRC%]\sources\boot.wim,{ramdiskoptions}
 if errorlevel 1 goto _ENG
 bcdedit /set %%B osdevice ramdisk=[%SRC%]\sources\boot.wim,{ramdiskoptions}
 bcdedit /set %%B path \windows\system32\winload.efi
 bcdedit /set %%B systemroot \windows
 bcdedit /set %%B winpe yes
 bcdedit /set %%B detecthal yes
 bcdedit /set %%B ems yes
 bcdedit /displayorder %%B /addlast
 bcdedit /timeout 10
 del GUIDTEMP.TXT
 goto _EXIT
)

:_ENG
for /F "tokens=3" %%C in (GUIDTEMP.TXT) do (
 bcdedit /set %%C device ramdisk=[%SRC%]\sources\boot.wim,{ramdiskoptions}
 bcdedit /set %%C osdevice ramdisk=[%SRC%]\sources\boot.wim,{ramdiskoptions}
 bcdedit /set %%C path \windows\system32\winload.efi
 bcdedit /set %%C systemroot \windows
 bcdedit /set %%C winpe yes
 bcdedit /set %%C detecthal yes
 bcdedit /set %%C ems yes
 bcdedit /displayorder %%C /addlast
 bcdedit /timeout 10
 del GUIDTEMP.TXT
 goto _EXIT
)

:_ADMIN
cls
echo.
echo.
echo.
echo          우클릭 해서 관리자 권한으로 실행해주세요.
echo.
echo.
echo.
pause
goto _EXIT

:_EXIT
exit
==================================================================================================

임의로 저장한 cmd 파일을 관리자 권한으로 실행 후 PC를 재부팅하여 부트메뉴에 "Windows7 64bit UEFI 설치" 선택
이후 기존과 같은 방법으로 윈도우 설치.
Clean 설치를 원하는 경우 시스템 파티션과 기존 OS파티션 삭제 후 할당되지 않은 영역을 선택하여 윈도우 설치 진행.(윈도우7 원본이 설치된 파티션은 지우면 안됨)